; conflict.ops

(literalize country
        name
        president)

(literalize person
        firstname
        city
        state)

(literalize state
        abbrev
        country
        statename
        population)

(literalize senator
        lastname
        from)

(startup
        (make person ^firstname jan ^city phoenix ^state AZ)
        (make state ^abbrev AZ ^statename arizona ^population 3700000
                    ^country USA)
        (make senator ^lastname McCain ^from AZ)
        (make senator ^lastname DeConcini ^from AZ)
        (make person ^firstname scott ^city phoenix ^state AZ)
        (make person ^firstname jackie ^city scottsdale ^state AZ)
        (make person ^firstname ron ^city glendale ^state IL)
        (make state ^abbrev IL ^statename illinois ^population 11500000
                    ^country USA)
        (make senator ^lastname Braun ^from IL)
        (make senator ^lastname Simon ^from IL)
        (make person ^firstname mark ^city chicago ^state IL)
        (make person ^firstname ryne ^city chicago ^state IL)
        (make person ^firstname deborah ^city |HOFFMAN ESTATES| ^state IL)
)

(p rule1
        (state ^country <country>)
      - (country ^name <country>)
-->
        (make country ^name <country>)
)

(p rule2
        (senator ^lastname <senator1> ^from <state>)
        (senator ^lastname {<senator2> <> <senator1>} ^from <state>)
-->
        (write (crlf) |The senators from | <state> | are:|
               (crlf)
               (crlf) <senator1>
               (crlf) <senator2>)
        (remove 1)
        (remove 2)
)

(p rule3
        (state ^abbrev <abbrev> ^population <pop>)
        (senator ^lastname <senator1> ^from <abbrev>)
        (senator ^lastname {<senator2> <> <senator1>} ^from <abbrev>)
      - (state ^population > <pop>)
-->
        (write (crlf) |The senators from the largest state (| <abbrev> |) are:|
               (crlf)
               (crlf) <senator1>
               (crlf) <senator2>)
        (remove 2)
        (remove 3)
)

(p rule4
        (state ^abbrev <abbrev> ^population {<pop> > 1000000 < 5000000})
        (senator ^lastname <senator1> ^from <abbrev>)
        (senator ^lastname {<senator2> <> <senator1>} ^from <abbrev>)
-->
        (write (crlf) |The senators from | <abbrev> | are:|
               (crlf)
               (crlf) <senator1>
               (crlf) <senator2>)
        (remove 2)
        (remove 3)
)

(p rule5
        (state ^abbrev <abbrev> ^statename <name>
               ^population {<pop> > 1000000 < 5000000})
        (senator ^lastname <senator1> ^from <abbrev>)
        (senator ^lastname {<senator2> <> <senator1>} ^from <abbrev>)
-->
        (write (crlf) |The senators from | <name> | are:|
               (crlf)
               (crlf) <senator1>
               (crlf) <senator2>)
        (remove 2)
        (remove 3)
)